string __MonitoringMedRegion;
string __MonitoringMedMO;
string __MonitoringMedMO_OID;
string __tablePseudo="formMed";
var MapNuRv=CreateObject("MapLong"); //виды из которых брать ФРВ
var MapNuSovm=CreateObject("MapLong"); //виды с оплатой внутреннего совместительства (когда не заводят отдельные исп должности)
var MapNuRest=CreateObject("MapLong"); //виды при наличии которых в отчет добавляем и нулевые строки
var MapDepartmentName=CreateObject("MapString"); 
var MapDepartmentOID=CreateObject("MapString"); 

var __propArray_415=CreateObject("APropArray");  //список источников с выплатами по пп 415
var __propArray_484=CreateObject("APropArray");  //список источников с выплатами по пп 484
bool __sortByFio=false;
bool __sortBySnils=false;
bool __mainDolgFirst=false;
bool __takeFRMRDolgnName=false;  // название должности определять через справочник ФРМР
bool __useOkpdtrDolgnName=false; // название должности определять через ОКПДТР
bool __frv_nrvFromMainProp=false;
bool __frvBySrc=false; //учитываем источник строки при выборке ФРВ "по видам"
bool __frvBySubj=false;//учитываем обьект строки при выборке ФРВ "по видам"
bool __frvByDep=false; //учитываем подразделение строки при выборке ФРВ "по видам"
bool __takeDepartmentNameFromSet=false;//брать наименование подразделение из сетки OID
bool __takeRKFromNu=false;
int __summFlag=CL_MV;  //флаг выборки сумм (по месяцу начисления/месяцу принадлежности)
string __prefixSnils="";
string reportKeyDelim="^";//разделитель значений
int __reportType;
int idxReportType_MinstryHealth       =1,     //"Форма для заполнения" (Минздрав)
    idxReportType_MinstryWork         =2,     //"Форма для заполнения" (Минтруд)
    idxReportType_MinstryWork04_2020  =3,     //"Форма для заполнения" (Минтруд) 04.2020   
    idxReportType_MinstryHealth04_2020=4;     //"Форма для заполнения" (Минздрав)04.2020   
InitMonitoringMed(reportType)
{
  __reportType=reportType;
  char BufCnf[256];
  GetCommonCnf("region",__tablePseudo,BufCnf,255);
  __MonitoringMedRegion=RTrimS(BufCnf);
	GetCommonCnf("MO",__tablePseudo,BufCnf,255);
  __MonitoringMedMO=RTrimS(BufCnf);
	GetCommonCnf("MO_OID",__tablePseudo,BufCnf,255);
  __MonitoringMedMO_OID=RTrimS(BufCnf);
  
	MapNuRv.Clear();
	GetCommonCnf("CllNU_Rv",__tablePseudo,BufCnf,255);
	var arr;
  int countElem =ListNUToSafeArray(BufCnf,' ',arr);
  for (int i=0;i<countElem;i++)   MapNuRv.Add(arr[i],i);
  
  int rkFromNu=GetCommonCnfInt ("rkFromNu", __tablePseudo);
  __takeRKFromNu=rkFromNu==1;
	
	MapNuSovm.Clear();
	GetCommonCnf("CllNU_Sov",__tablePseudo,BufCnf,255);
	var arr2;
	int countElem2 =ListNUToSafeArray(BufCnf,' ',arr2);
  for (int i=0;i<countElem2;i++)   MapNuSovm.Add(arr2[i],i);
	
	MapNuRest.Clear();
	GetCommonCnf("CllNU_Rest",__tablePseudo,BufCnf,255);
	var arr3;
	int countElem3 =ListNUToSafeArray(BufCnf,' ',arr3);
  for (int i=0;i<countElem3;i++)   MapNuRest.Add(arr3[i],i);
	
	
	GetCommonCnf("prefixSnil",__tablePseudo,BufCnf,255);
	__prefixSnils=RTrimS(BufCnf);
	
  int howFrvCalc=GetCommonCnfInt ("howFrvCalc", __tablePseudo);
	__frv_nrvFromMainProp=howFrvCalc & 0x01;
  
  int howSumCalc=GetCommonCnfInt ("howSumCalc", __tablePseudo);
	__summFlag=howSumCalc==1?CL_MV:CL_M;
  
  int frvBySrc=GetCommonCnfInt ("frvBySrc", __tablePseudo);
  __frvBySrc   = frvBySrc & 0x01;
  __frvBySubj  = frvBySrc & 0x02;
  __frvByDep   = frvBySrc & 0x04;

	int howSort=GetCommonCnfInt ("howSort", __tablePseudo);
	__sortByFio    =howSort & 0x01;
	__sortBySnils  =howSort & 0x02;
	__mainDolgFirst=howSort & 0x04;
	
	int howDefineDolgnName=GetCommonCnfInt ("howDefDolg", __tablePseudo);
	__takeFRMRDolgnName=howDefineDolgnName & 0x01;
  __useOkpdtrDolgnName=howDefineDolgnName & 0x04;
  int takeDepartmentNameFromSet=GetCommonCnfInt("howGetPodr", __tablePseudo);
  __takeDepartmentNameFromSet=takeDepartmentNameFromSet!=0;
  int setNumber=GetCommonCnfInt ("podrOidSet", __tablePseudo);
 
  MapDepartmentName.Clear(); 
  MapDepartmentOID.Clear(); 
  char dir[256];char str[256];
  GetCommonZPL(dir,255);//определяем путь до сетевого ЗПЛ -справочник берем из него
  sprintf(str,"%s\\TABLSET2\\Tabl%d.sum",dir,setNumber);  // путь до справочника
  var   CTabl = CreateObject("CurPrnTbl");
  CTabl.InitialNameFile(to_string(str));
  int cr=CTabl.Count_Rcr();         // число рабочих записей в таблице    
  
  int idxFldDepartmentCode=CTabl.Find_Name_Fld("FCpodr");
	int idxFldDepartmentName=CTabl.Find_Name_Fld("podrName");
  int idxFldDepartmentOID =CTabl.Find_Name_Fld("podrOID");
  // цикл по записям таблицы
  for (int zap=0; zap<cr; zap++)
  {
    int departmentCode=atoi(CTabl.Text(idxFldDepartmentCode,zap));
    if (!departmentCode) continue; //пропускаем пустые строки
    
    string departmentName=RTrimS(CTabl.Text(idxFldDepartmentName,zap));
    string departmentOID=RTrimS(CTabl.Text(idxFldDepartmentOID,zap));
    if (!MapDepartmentName.IsExist(to_string(departmentCode)))
    {
      MapDepartmentName.Add(to_string(departmentCode),departmentName);
      MapDepartmentOID.Add(to_string(departmentCode),departmentOID);
    }
  }
  //источники с выплатами по пп 415
  string srcList="";
  var prop=CreateObject("APropBE");
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC06",__tablePseudo));
	if(strlen(srcList))
  {
    prop.LoadFromStr(srcList);
    __propArray_415.Insert(prop);
  }
	
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC07",__tablePseudo));
	if(strlen(srcList))
	{
    prop.LoadFromStr(srcList);
    __propArray_415.Insert(prop);
  }
	srcList=RTrimS(GetCommonCnfStr("LIST_SRC08",__tablePseudo));
	if(strlen(srcList))
	{
    prop.LoadFromStr(srcList);
    __propArray_415.Insert(prop);
  }
	srcList=RTrimS(GetCommonCnfStr("LIST_SRC09",__tablePseudo));
	if(strlen(srcList))
	{
    prop.LoadFromStr(srcList);
    __propArray_415.Insert(prop);
  }
	
  //источники с выплатами по пп 484
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC10",__tablePseudo));
	if(strlen(srcList))
	{
    prop.LoadFromStr(srcList);
    __propArray_484.Insert(prop);
  }
}
//получаем данные для таблицы
GetTableRow()
{
	int reportPeriodMB = KDateFromStr(Str_Date_0).GetAbs();
  int reportPeriodME = KDateFromStr(Str_Date_1).GetAbs();
	try
  {
    var kcp = CreateObject("KPeriodsIterations");kcp.ClearAll();
		//цикл по всем Aprop в ЛС
		var APropArr=CreateObject("APropArray");APropArr.GetPropListLS();
	  for ( int idxAprop=0; idxAprop<APropArr.Size();  idxAprop++ )
		{
			var curProp=APropArr.Get(idxAprop);
			//цикл по месяцам
			for(int month=reportPeriodMB;month<=reportPeriodME;month++)
			{
				kcp.AddPeriod(MakeRecordKey(month,curProp,false),to_string(datatek),to_string(datatek));//"добавляем"  строку в таблицу
				if(MapNuSovm.Size() && nabs(GetReportSummNuList(curProp,month,StrFromMap(MapNuSovm," "),__summFlag))>0.001) //указаны виды для сов-ва + по видам есть суммы -> добавляем строку с "фиктивным" внутренним совместительством
					kcp.AddPeriod(MakeRecordKey(month,curProp,true),to_string(datatek),to_string(datatek));
			}	
		}	
  }
  catch(object err)
  {
    SayError(err);                  //выводим сообщение о ошибке
  }
  catch(...)
  {
    SayUndefinedScriptError();
  }
}

GetDolgnName(prop,month,btakeFRMR)
/*
если есть должность ФРМР - берем ее
если есть должность ОКПДТР - берем ее
иначе берем то название должности что используется в организации.
*/
{
	if(prop.GetCombine()==-1)
		return "Должность внутреннего совместительства не определена";
	var doljnElem=GetDoljnFromKCH(KDateFromInt_LastDay(month).GetStr(),prop.GetCombine());
	if(doljnElem.IsEmpty())
		return "Должность не определена";
  
  //если есть должность ФРМР - берем ее	
	if(btakeFRMR && doljnElem.GetFrmrCode()!=0)
		return RTrimS(doljnElem.GetFrmrName());
	
  //если есть должность ОКПДТР - берем ее	
  if(__useOkpdtrDolgnName && doljnElem.GetOKPDTRCode()!=0)
		return GetOKPDTRDoljnName(doljnElem.GetOKPDTRCode()); 
  
  //берем должность из К.Ч.  
	return RTrimS(doljnElem.GetName());
}
GetDolgnDepartmentName(prop,month,params)
{
	return PriorityCall("UserGetDolgnDepartmentName","SysGetDolgnDepartmentName",prop,month,params);
}
SysGetDolgnDepartmentName(prop,month,params)
{
	//можно брать название из подразделения указанного в строке вида
	//todo:названия подразделений  контролировать по справочнику формы- предупредить
	if (prop.GetCombine()==-1)
		return "Подразделение внутреннего совместительства не определено";
	var departmentCode=DolgnDepartmentCode(prop.GetCombine(),month);

  if(__takeDepartmentNameFromSet && MapDepartmentName.IsExist(to_string(departmentCode)))
    return MapDepartmentName.GetValue(to_string(departmentCode));

	return RTrimS(GetOtdName(departmentCode));
}
DolgnDepartmentCode(combine,month)
{
	var doljnElem=GetDoljnFromKCH(KDateFromInt_LastDay(month).GetStr(),combine);
	if(doljnElem.IsEmpty()||doljnElem.GetPodr()==0)
	{
		var CL=CreateObject("CombineList");
		if(CL.GetPodr(combine)>0)
			return CL.GetPodr(combine);
		return kch_from_int("podr");//-1; todo: может все же лучше возвращать -1?
	}	
	return doljnElem.GetPodr();
}
GetWorkTypeName(prop,month,params)
{
	return PriorityCall("UserGetWorkTypeName","SysGetWorkTypeName",prop,month,params);

}
SysGetWorkTypeName(prop,month,params)
{
	if (IsEmployeeExtSovm(month))
		return "Внешнее совместительство";
	if(prop.GetCombine()==GetGeneralCombineLS())
		return "Основное";
	return "Внутреннее совместительство";
}
IsEmployeeExtSovm(month)
{
	var d=KDateFromInt_LastDay(month);
	char s[256];GetKchValue("kod_rab",s,99,d);
	return atoi(s)==4||atoi(s)==9;
}
GetDolgnStavka(prop,month)
{
  if(prop.GetCombine()==-1)
		return -1;
  return DefineKEmploy(prop.GetCombine(),KDateFromInt_LastDay(month));
}


GetDolgnDepartmentOID(prop,month,params)
{
  if (prop.GetCombine()==-1)
		return "OID подразделения не определен";
  
  var departmentCode=DolgnDepartmentCode(prop.GetCombine(),month);
  if (!MapDepartmentOID.IsExist(to_string(departmentCode)))
		return "OID подразделения не определен";
  
  return MapDepartmentOID.GetValue(to_string(departmentCode));
}
GetSrcType(prop)
{
	var multiPropArray= CreateObject("MultiPropArray");
	
	string srcList=RTrimS(GetCommonCnfStr("LIST_SRC01",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "ОМС";	
	}
	
	srcList=RTrimS(GetCommonCnfStr("LIST_SRC02",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Средства бюджета на финансовое обеспечение государственного задания";	
	}

	srcList=RTrimS(GetCommonCnfStr("LIST_SRC03",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Субсидии из средств бюджета";	
	}

	srcList=RTrimS(GetCommonCnfStr("LIST_SRC04",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Средства от платных мед услуг";	
	}
	
	
	srcList=RTrimS(GetCommonCnfStr("LIST_SRC05",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Иные средства от приносящих доход деятельности";	
	}
	
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC06",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Субсидия федерального бюджета по ПП РФ № 415";	
	}
  
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC07",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Субсидия бюджета субъекта Российской Федерации по ПП РФ №415";	
	}
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC08",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Субсидия бюджета органа местного самоуправления по ПП РФ №415";	
	}
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC09",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Иные источники софинансирования по ПП РФ №415";	
	}
  srcList=RTrimS(GetCommonCnfStr("LIST_SRC10",__tablePseudo));
	if(strlen(srcList))
	{
		multiPropArray.LoadFromStr(srcList);
		if(multiPropArray.IsElemValid(prop))
			return "Субсидия федерального бюджета по ПП РФ №484";	
	}
  return "Источник не определен";
}
GetFrvMed(prop,month,isSovmByNu)
{
	return PriorityCall("UserGetFrvMed","SysGetFrvMed",prop,month,isSovmByNu);
}
SysGetFrvMed(prop,month,isSovmByNu)
{
	//настройка брать РВ с главного, но prop не главный 
	if(__frv_nrvFromMainProp && !prop.IsEQ(GetLsMainProp()))
		return 0.;
	
	double totalRv=0.;
	if(!isSovmByNu && MapNuRv.Size()<1)//берем ФРВ из табеля 
	{
		var tmpComb=CreateObject("TmpCurCombine");tmpComb.Init(prop.GetCombine()); //устанавливаем должность текущей

		int tmpMrasch = mrasch;
		s50(month);
		skoljko(totalRv,data,1,countday,rsimv,calm,cht);
		if ( mrasch!=tmpMrasch )
			s50(tmpMrasch);
	}
	else //берем РВ из видов
	{
		var propTmp = CreateObject("APropBE");propTmp.Init(CLL_TOTAL_SRC,CLL_TOTAL_SUBJECT,CLL_TOTAL_PODR,prop.GetCombine());
    if(__frvBySrc)
      propTmp.SetSrc(prop.GetSrc());
    if(__frvBySubj)
      propTmp.SetSubject(prop.GetSubject());
    if(__frvByDep)
      propTmp.SetPodr(prop.GetPodr());
    
		if(isSovmByNu)
		{
			//ФРВ берем из видов, указанных в настройках CllNU_Rv И CllNU_Sov
			if( MapNuRv.Size()<1 || MapNuSovm.Size()<1 )
				return 0.;
			
			string nuList=GetNuListIntersect(StrFromMap(MapNuRv," "),StrFromMap(MapNuSovm," "));
			var arr;
			int countElem =ListNUToSafeArray(nuList,' ',arr);
			for (int i=0;i<countElem;i++)   
				totalRv+=CashSummProp(0,arr[i],month,month,42,CL_SOURCE|__summFlag,propTmp); 
		}
		else 
		{
			//todo - брать РВ только из тех строк, по которым есть суммы...
			for (bool Cur=MapNuRv.InitIterator();Cur;Cur=MapNuRv.Next())
			{
				int code =atoi(MapNuRv.GetCurKey());
				//виды, указанные в MapNuSovm в расчет РВ не берем
				if(MapNuSovm.IsExist(code))
					continue;				
				//int Flags=(bSumNach)? CL_SOURCE|CL_MV:CL_SOURCE|CL_M;
				totalRv+=CashSummProp(0,code,month,month,42,CL_SOURCE|__summFlag,propTmp); 
			}
		}	
	}
	//округляем до 2х знаков после запятой
	roundd(totalRv, 2, totalRv);
	return totalRv;
}
//для пп 415 и 484 рв всегда берем из видов (т.к. непонятно как из общего табеля вычленить РВ по конкретному пп) 
GetFrvMedFiltered(prop,month,isSovmByNu,filterPropArray)
{
	double totalRv=0.;
	if( __frv_nrvFromMainProp && !prop.IsEQ(GetLsMainProp()) //настройка брать РВ с главного, но prop не главный 
      || MapNuRv.Size()<1                                  //незаполнена настройка "виды из которых брать ФРВ"
      || filterPropArray.FindTotal(prop)==-1)              //prop не содержится в filterPropArray  
		return 0.;
	
  //берем РВ из видов
	{
		var propTmp = CreateObject("APropBE");propTmp.Init(CLL_TOTAL_SRC,CLL_TOTAL_SUBJECT,CLL_TOTAL_PODR,prop.GetCombine());
    if(__frvBySrc)
      propTmp.SetSrc(prop.GetSrc());
    if(__frvBySubj)
      propTmp.SetSubject(prop.GetSubject());
      if(__frvByDep)
      propTmp.SetPodr(prop.GetPodr());
    
		if(isSovmByNu)
		{
			//ФРВ берем из видов, указанных в настройках CllNU_Rv И CllNU_Sov
			if( MapNuRv.Size()<1 || MapNuSovm.Size()<1 )
				return 0.;
			
			string nuList=GetNuListIntersect(StrFromMap(MapNuRv," "),StrFromMap(MapNuSovm," "));
			var arr;
			int countElem =ListNUToSafeArray(nuList,' ',arr);
			for (int i=0;i<countElem;i++)   
				totalRv+=CashSummProp(0,arr[i],month,month,42,CL_SOURCE|__summFlag,propTmp); 
		}
		else 
		{
			//todo - брать РВ только из тех строк, по которым есть суммы...
			for (bool Cur=MapNuRv.InitIterator();Cur;Cur=MapNuRv.Next())
			{
				int code =atoi(MapNuRv.GetCurKey());
				//виды, указанные в MapNuSovm в расчет РВ не берем
				if(MapNuSovm.IsExist(code))
					continue;				
				//int Flags=(bSumNach)? CL_SOURCE|CL_MV:CL_SOURCE|CL_M;
				totalRv+=CashSummProp(0,code,month,month,42,CL_SOURCE|__summFlag,propTmp); 
			}
		}	
	}
	//округляем до 2х знаков после запятой
	roundd(totalRv, 2, totalRv);
	return totalRv;
}
GetNrvMed(prop,month,isSovmByNu)
{
	return PriorityCall("UserGetNrvMed","SysGetNrvMed",prop,month,isSovmByNu);
}
SysGetNrvMed(prop,month,isSovmByNu)
{
	//todo может брать норму из графика, указанного для вида, из которого берем ФРВ? + вид должен быть указан в CllNU_Sov  
	//!!! в ЛС может быть несколько видов сов-ва и у каждого вида свой график...
	//надо в этом случае группировать информацию по графикам и показывать каждый график отдельным сов-вом
	if(isSovmByNu)
		return 0.;
	
	//настройка брать РВ с главного, но prop не главный 
	if(__frv_nrvFromMainProp && !prop.IsEQ(GetLsMainProp()) )
		return 0.;
		
	var tmpComb=CreateObject("TmpCurCombine");tmpComb.Init(prop.GetCombine()); //устанавливаем должность текущей
  //определяем номер графика на конец месяца
  char tmp[256];
  GetKchValue("grafik",tmp,10,KDateFromInt_LastDay(month));
  int nomerGR=atoi(tmp);
  if (!nomerGR) 
		nomerGR=1;
	int tmpMrasch = mrasch;
	s50(month);
  //грузим нужный график
  rwnorma(nomerGR,0);
  s118();
	double nrv=norm(2);
	if ( mrasch!=tmpMrasch )
    s50(tmpMrasch);
	
	//округляем до 2х знаков после запятой
	roundd(nrv, 2, nrv);
  return nrv;
}
GetNuListIntersect(nuList1,nuList2)
{
	var map=CreateObject("MapLong");map.Clear();
	var arr;
	int countElem =ListNUToSafeArray(nuList2,' ',arr);
  for (int i=0;i<countElem;i++)   
		map.Add(arr[i],i);
	//нет видов во втором списке...
	if (map.Size()<1)
		return "";
	
	
	var newNuList="";
	var arr1;
	int countElem1 =ListNUToSafeArray(nuList1,' ',arr1);
  for (int i=0;i<countElem1;i++)
  {
		if ( !map.IsExist(to_string(arr1[i])))
			continue;
    //добавляем к результату только те виды из списка1, которые есть в списке2
		newNuList+=	to_string(arr1[i])+" ";	
	}
	return newNuList;
}
GetNuListExcept(nuList1,nuList2)
{
	var map=CreateObject("MapLong");map.Clear();
	var arr;
	int countElem =ListNUToSafeArray(nuList2,' ',arr);
  for (int i=0;i<countElem;i++)   
		map.Add(arr[i],i);
	//нет видов во втором списке...
	if (map.Size()<1)
		return nuList1;
	
	
	var newNuList="";
	var arr1;
	int countElem1 =ListNUToSafeArray(nuList1,' ',arr1);
  for (int i=0;i<countElem1;i++)
  {
		if ( map.IsExist(to_string(arr1[i])))
			continue;
    //добавляем к результату только те виды из списка1, которых нет в списке2
		newNuList+=	to_string(arr1[i])+" ";	
	}
	return newNuList;
}
//сумма по набору внутренних кодов видов nuList
//Flag:CL_M  - сумма по месяцу принадлежности 
//     CL_MV - сумма по месяцу начисления
GetReportSummNuList(prop,month,nuList,Flag)
{
	bool bNach = (Flag & CL_MV) ? true: false; 
	var arr;
	int cntNu=ListNUToSafeArray(nuList,' ',arr);
	if(cntNu<1)
		return 0.;
	
	double rez=0.;
	for(int i=0;i<cntNu;i++)
	{
		int code=arr[i];
		if(bNach)
			rez+=CollectSummProp(code,0,month,Flag,prop);
		else
			rez+=CollectSummProp(code,month,0,Flag,prop);
	}
	return rez;
}
//прочие функции
GetSummGroup(prop,month,groupNum,isSovmByNu)
{
	//todo: есть информация что оклад (группа 1) надо показывать не фактически начисленный, а нормативный..
	char nuList[256];
	GetCommonCnf("CllNU_"+to_string(groupNum),__tablePseudo,nuList,255);
	if( isSovmByNu ) //ищем пересечение с MapNuSovm
	{
		if( MapNuSovm.Size()<1 )
			return 0.;
		nuList=GetNuListIntersect(nuList,StrFromMap(MapNuSovm," "));
	}
	else if (MapNuSovm.Size()>0)//исключаем виды, указанные в MapNuSovm
		nuList=GetNuListExcept(nuList,StrFromMap(MapNuSovm," "));

		return GetReportSummNuList(prop,month,nuList,__summFlag);
}
GetSummGroupFiltered(prop,month,groupNum,isSovmByNu,filterPropArray)
{
  if( filterPropArray.FindTotal(prop)==-1)              //prop не содержится в filterPropArray  
		return 0.;
  return GetSummGroup(prop,month,groupNum,isSovmByNu);  
}
DefineRkByProp(prop,month)
{
  var date=KDateFromInt_LastDay(month);
  if(__takeRKFromNu)
  {
    //пытаемся найти действующую строку РК
    //если БЗ вида непустое - возвращаем значение БЗ
    char nuList[256];	GetCommonCnf("CllNU_3",__tablePseudo,nuList,255);
    var arr;
    int cntNu=ListNUToSafeArray(nuList,' ',arr);
    for(int i=0;i<cntNu;i++)
    {
      int code=arr[i];
      int row=TryFindCodeValidOnDateByProp(prop,code,date);  
      if ( row==-1 || GetBase(row)<0.001 )
        continue;
      return 1.+GetBase(row)/100.; 
    }
  }
  return 1.+DefineRkFull(date.GetDouble(),false);
}
TryFindCodeValidOnDateByProp(prop,intCode,kDate)
{
  int rowkod[ROWMAX];//массив с номерами строк
  int cntrow=poiskosnkodProp(intCode,rowkod,0,prop);//получаем список строк с кодом==kod
  for (int row=0; row<cntrow; row++)  
  {
    double ikod=GetCode(rowkod[row]);
    var dbRow=KDateFromD(GetBegDate(rowkod[row]));
    var deRow=KDateFromD(GetEndDate(rowkod[row]));
    if (dbRow.IsValid() && dbRow.GT(kDate)) //вид еще не открыт
      continue;
    
    if (deRow.IsValid() && deRow.LT(kDate)) //вид закрыт
      continue;
      
    return rowkod[row];  
  }
  return -1;  
}
NeedMergeRv()
{
  int frvBySrc=GetCommonCnfInt ("frvBySrc", __tablePseudo);
  if(frvBySrc>0 && MapNuRv.Size()>0) //нужно выставить флаг "суммируемое поле" для полей с ФРВ
    return true;
  return false;
}
GetSnilsPartSortKey()
{
	if( !__sortByFio && !__sortBySnils )
		return "";
	if(__sortByFio)
		return GetFioFromKch();
	return GetSnilsDigits();
}
GetMainDolgnPartSortKey(workTypeName)
{
	if(!__mainDolgFirst)
		return "";
	
	return workTypeName=="Основное"?"1":"2";
}
GetSnilsDigits()
{
	char Buf[256];kch_from("strah_n",Buf);Buf=RTrimS(Buf);
  char digits[256];           // тут будет результат
  // Копируем в digits только цифры
  int digitCount=0;
  for (int i=0; i<strlen(Buf); i++)
    if (Buf[i]>='0' && Buf[i]<='9')
      digits[digitCount++] = Buf[i];

	return to_string(digits);
}
GetReportValue(idx)
{
	var kcp = CreateObject("KPeriodsIterations");
	return Split(kcp.GetCurCod(),reportKeyDelim)[idx];
}
CalcFlagSumm(res)
{
	for(int idx=idxSum1;idx<=idxLastSumm;idx++)
	{
    //для отчета минздрава не учитываем столбцы  РК и Северная надбавка
    if( __reportType==idxReportType_MinstryHealth04_2020 && ( idx==idxRk_415 || idx==idxRk_484 || idx==idxSev_415) )
      continue;
		//нашли ненулевую сумму
		if(nabs(atof(Split(res,reportKeyDelim)[idx]))>0.00001)
			return 1;
	}
	return 0;
}
CalcFlagRest(month,curProp)
{
	if (nabs(GetReportSummNuList(curProp,month,StrFromMap(MapNuRest," "),CL_M))>0.00001)
		return 1;
	return 0;
	/*
	int bFindRest=0;
	//смотрим наличие в табеле символов "ОДТ"
	int combine=atoi(Split(res,reportKeyDelim)[idxSummComb]);
	var tmpComb=CreateObject("TmpCurCombine");tmpComb.Init(combine); //устанавливаем должность текущей
	
	int month=atoi(Split(res,reportKeyDelim)[idxMonthAbs]);
  int tmpMrasch = mrasch;
	s50(month);
	
	for ( int day=1; day <= countday; day++ )
		if (calm[day-1]=='О' ||
				calm[day-1]=='Д' ||
				calm[day-1]=='Т' 	 )
		{
			bFindRest=1;
			break;
		}
					
	if ( mrasch!=tmpMrasch )
		s50(tmpMrasch);
	
	return bFindRest;
	*/
}
//печатаем для Минтруда 
PrintMonitoringMinistryWork()
{
  PrintMonitoringBase(idxReportType_MinstryWork);
}
PrintMonitoringMinistryWork04_2020()
{
  PrintMonitoringBase(idxReportType_MinstryWork04_2020);
}
//печатаем для Минздрава 
PrintMonitoringMed()
{
  PrintMonitoringBase(idxReportType_MinstryHealth);
}
//печатаем для Минздрава 
PrintMonitoringMed04_2020()
{
  PrintMonitoringBase(idxReportType_MinstryHealth04_2020);
}

    
PrintMonitoringBase(reportType)
{
	InitMonitoringMed(reportType);
	var CFile=CreateObject("CurPrnFile"); // объект класса для работы с текущим файлом печати
  CFile.SetFlagBrowse(0);
  CFile.SetFlag_Print(0);

	 char Dir[128];                              // строка для текущей директории
   GetCurrentDirectory(128,Dir);               // получаем текущую директорию (это корень каталога ZPL из которого запустили АМБу)
   
   string fileName="\\monitoringMed.xlt";
   if( reportType==idxReportType_MinstryWork )
    fileName="\\monitoringMinistryWork.xlt";
   else if ( reportType==idxReportType_MinstryWork04_2020 )   
    fileName="\\monitoringMinistryWork_2020.xlt";
   else if( reportType==idxReportType_MinstryHealth04_2020 )   
    fileName="\\monitoringMed2020.xlt";

   string nm="\\"+NameCommonDir()+fileName;

   char NameXlt[256];
   NameXlt = Dir+nm;

   // если шаблона нет, на лок.машине, и версия сетевая...то берем шаблон с
   // серверной машины
   if ( !IsLocalZPL() && IsCommonResource(NameCommonDir()) )
   {
      //берем путь к сетевому ZPL 
      GetCommonZPL(NameXlt,255);
      NameXlt = NameXlt+nm;
   }

   tPrepereOfficeForWork(); // определяем работать на Excel или на Calc (определяем какой из офисов (MS Office или OpenOffice) установлен и какой предпочтительнее)
	 tOpenXlsObjects(to_string(NameXlt),""); 
   string wshName= (reportType==idxReportType_MinstryHealth) ? "Лист1" : "Таблица 1";
   tGetWshByName(OemToAnsi(wshName));
   //tGetWshByIndex(1); // получаем ссылку на лист (worksheet)
   tWshSelect();

	 var CTabl=CreateObject("CurPrnTbl");  // объект класса для работы с текущей таблицей
  
  var CMsg = 0;    // Процент выполненной работы
  int bTime = false;   // false-показывать процент,
                      // true-показывать оставшееся время
  CMsg=CreateObject("ProgressBar");
  CMsg.Initial(0,100,1);
  CMsg.SetShowTime(static_cast_to_int(bTime));

	int idxFldFlagSumm=CTabl.Find_Name_Fld("flagSumm");
	int idxFldFlagRest=CTabl.Find_Name_Fld("flagRest");
	try
  {
		//int excelRow=4;//начинаем печатать в 4 строку
    int excelRow=reportType==idxReportType_MinstryWork04_2020?5:4;//начинаем печатать в 4 строку
    int npp=0;//порядковый номер строки
	  // цикл по записям таблицы
   for (int record=0; record<CTabl.Count_Rcr(); record++)
   {
		  if ( CMsg.Msg_Proc(" Подождите немного. Идет подготовка к печати. ",100.*record/CTabl.Count_Rcr())==ESC )    { break;}
		 
		  bool haveSumm=idxFldFlagSumm==-1||atoi(CTabl.Text(idxFldFlagSumm,record))>0;
		  bool haveRest=idxFldFlagRest==-1||atoi(CTabl.Text(idxFldFlagRest,record))>0;
			if ( !haveSumm && !haveRest) 
				continue;
		   
			if( reportType==idxReportType_MinstryWork04_2020 )  
        npp++;
			PrintOneRow(CTabl,record,excelRow++,npp);
	 }
	//удаляем 3 строки из шаблона
  tDeleteRows(excelRow,3); 	
  // чтобы не было выделенной строки после всех манипуляций с копированием
  // выделим отдельную ячейку.
  tWshCellSelect(4,1);       
  } // блок try
  catch(object err)
  {
    tEndXlsWork(1); // делаем форму видимой
    SayError(err);
    return 1;
  }
  catch(...)
  {
    SayUndefinedScriptError();
  }
  tEndXlsWork(1); // делаем форму видимой
  return 0;
}
/*PrintOneRow(&CTabl,record,excelRow)
{
	tInsertRows(excelRow+1,1);tCopyRow(excelRow+2);
	int excelColumn=1;
	for(int column=0;column<CTabl.Count_Fld();column++) 
	{
		if ( !IsSubStrPresent(CTabl.Flag_Print_Fld(column),"+") )
			continue;
		
		string value=RTrimS(CTabl.Text(column,record));
		tWriteStringToCell2(excelRow,excelColumn++,OemToAnsi(value));
	}
}*/
PrintOneRow(&CTabl,record,excelRow,npp)
{
	tInsertRows(excelRow+1,1);tCopyRow(excelRow+2);
  if (npp>0)
    tWriteStringToCell2(excelRow,1,npp);
	int excelColumn=npp>0?2:1; //если нпп ненулевой -в первой колонке выводим нпп
	for(int column=0;column<CTabl.Count_Fld();column++) 
	{
		if ( !IsSubStrPresent(CTabl.Flag_Print_Fld(column),"+") )
			continue;
		
		string value=RTrimS(CTabl.Text(column,record));
		tWriteStringToCell2(excelRow,excelColumn++,OemToAnsi(value));
	}
}